Jika anda bermaksud menghitung
umur dengan microsoft excel dengan cara langsung memasukkan rumus excel
mengurangi tanggal sekarang dengan tanggal lahir maka hasil yang anda peroleh
tidak akan sesuai dengan keinginan. Kenapa? hal ini disebabkan excel menggunakan
nomor seri dalam format tanggalnya seperti yang sudah saya singgung sedikit
pada postingan sebelumnya tentang beberapa fungsi yang berkaitan dengan tanggal
dalam Microsoft Excel.
Perlu diketahui bahwa nomor seri
atau angka 1 jika anda format tanggal maka akan menghasilkan 1 Januari 1900 dan
angka 2 akan menghasilkan 2 Januari 1900, sedangkan pada saat saya menulis
artikel ini yakni 4 April 2016 nomor seri atau format angkanya adalah
"42464".
Lalu bagaimana cara menghitung
umur dengan microsoft Excel? Untuk menghitung Umur di excel, ada beberapa cara
yang bisa anda lakukan. Sebelum itu, barangkali anda mau membaca dulu tentang
sedikit perbedaan rumus dan fungsi dalam excel.
A. MENGHITUNG UMUR DI EXCEL DENGAN RUMUS MATEMATIKA UMUM
Dalam 1 tahun masehi ada 365
hari. Untuk menghitung umur dalam satuan tahun anda bisa membagi selisih
tanggal sekarang dan tanggal lahir dengan angka 365. Dalam rumus excel seperti
berikut:
Rumus Excel
=(TglSekarang - TglLahir)/365
Untuk mendapatkan tanggal
berjalan atau tanggal hari ini kita bisa menggunakan fungsi TODAY. Sehingga
rumus excelnya menjadi:
Rumus Excel
=(TODAY() - TglLahir)/365
Seperti pada contoh diatas rumus
tanggal lahir ini akan menghasilkan angka desimal. Untuk membulatkan atau
mengurangai jumlah angka desimal dibelakang koma tersebut bisa anda gunakan
fitur Decrease decimal yang ada di menu Home--Number.
Jika menghendaki angka bulat atau
tanpa desimal, maka gunakanlah Fungsi INT pada excel, sehingga rumusnya
menjadi:
Rumus Excel
=INT((TODAY() - TglLahir)/365)
Apabila menghendaki hasil akhir
ditambah dengan teks "Tahun" maka anda bisa menggunakan operator
excel "&" untuk ditambahkan pada umur dalam satuan tahun
tersebut. Jika digabung rumus excelnya menjadi:
Rumus Excel
=INT((TODAY() -
TglLahir)/365)&" Tahun"
Cara menghitung umur diatas
ternyata masih menyisakan masalah sebab tidak semua tahun umurnya 365 hari,
Kita tahu umur tahun kabisat adalah 366. Untuk itu mari kita coba cara lain.
B. MENGHITUNG UMUR DENGAN FUNGSI "YEARFRAC" EXCEL
Pada rumus excel, Fungsi
"YEARFRAC" menghasilkan bilangan atau angka desimal yang menunjukkan
periode tahun dari selisih dua tanggal.
Sintaksis atau cara menggunakan
YEARFRAC untuk menghitung umur di excel adalah sebagai berikut:
Rumus Excel
=YEARFRAC(TglLahir;
TglSekarang;1)
Argumen 1 pada fungsi YEARFRAC
diatas berarti bahwa perhitungan tahun didasarkan pada jumlah aktual pada
setiap bulan diantara dua tanggal tersebut. Berikut contoh penerapannya untuk
menghitung umur.
Selain menggunakan fungsi INT
anda juga bisa menggunakan fungsi pembulatan semisal fungsi ROUNDDOWN untuk
meghilangkan angka desimal yang dihasilkan oleh fungsi atau rumus YEARFRAC
diatas.
Rumus-rumus excel diatas hanya
menghasilkan angka tahun saja. untuk mendapatkan umur dalam satuan bulan dan
hari maka gunakan cara berikutnya ini.\
C. MENGHITUNG UMUR DENGAN FUNGSI "DATEDIF" EXCEL
Pada microsoft excel Fungsi
"DATEDIF" digunakan untuk menghitung jumlah hari, bulan, atau tahun
di antara dua tanggal.
Perlu anda ketahui bahwa fungsi
Datedif ini tidak akan kita temukan di tab formula excel. Sebab sebenarnya
fungsi ini merupakan fungsi LOTUS123 dan masih cukup berguna untk digunakan
terlebih untuk mencari atau menghitung umur atau usia.=
Untuk mengaktifkan fungsi datedif
yang tidak ada pada tab formula atau insert function pada formula bar, anda
harus menulis atau mengetikkan rumus datedif ini secara manual.
Jika rumus DATEDIF yang anda
gunakan menghasilkan error #NAME kemungkinan anda salah menuliskan rumusnya.
Yang benar DATEDIF dan bukan DATEIF.
CARA MENGGUNAKAN FUNGSI DATEDIF
Berikut cara menggunakan rumus
DATEDIF pada excel:
Sintaks Fungsi
DATEDIF(TglAwal;TglAkhir;satuan)
*Ingat dan catat: DATEDIF bukan
DATEIF.
ARGUMENT FUNGSI DATEDIF
Fungsi DATEDIF memiliki tiga
argument yakni TglAwal, TglAkhir, dan satuan:
- TglAwal : Berisi tanggal yang menunjukkan tanggal yang lebih dahulu, atau tanggal dimulainya periode. Atau dalam kasus mencari umur kita isi dengan tanggal lahir.
- TglAkhir : Tanggal yang menunjukkan tanggal terakhir, atau tanggal berakhirnya periode. Dalam kasus mencari usia kita isi dengan tanggal saat ini (NOW() atau TODAY()).
- Satuan : Kita isi dengan kode informasi yang ingin kita dapatkan. Untuk argument satuan, kode yang bisa kita masukkan antara lain:
1. "Y" : Jumlah total tahun yang sudah berlalu
dalam periode.
2. "M" : Jumlah total bulan yang sudah berlalu
dalam periode.
3. "D" : Jumlah total hari dalam periode.
4. "MD" : Selisih antara hari dalam TglAwal dan
TglAkhir. Bulan dan tahun dari tanggal diabaikan.
5. "YM" : Selisih antara bulan dalam TglAwal dan
TglAkhir. Hari dan tahun dari tanggal diabaikan
6. "YD" : Selisih antara hari dalam TglAwal dan
TglAkhir. Tahun dari tanggal diabaikan.
Perhatikan gambar berikut untuk
lebih jelasnya:
CONTOH FUNGSI DATEDIF
Untuk mendapatkan umur dalam
satuan tahun anda bisa menggunakan rumus datedif berikut:
Rumus Excel
=DATEDIF(TglAwal;TglAkhir;"Y")
Sedangkan untuk menghitung umur
sisa bulannya gunakan rumus datedif berikut:
Rumus Excel
=DATEDIF(TglAwal;TglAkhir;"YM")
Rumus di atas tidak akan
menghitung jumlah bulan yang sudah genap 1 tahun atau 12 bulan dari tanggal
lahir.
Adapun untuk jumlah hari gunakan
rumus datedif excel di bawah ini:
Rumus Excel
=DATEDIF(TglAwal;TglAkhir;"MD")
Sekarang perhatikan gambar
berikut sebagai contoh penggunaan fungsi DATEDIF dalm menghitung umur atau
usia.
1. Buatlah Tabel seperti gambar diatas
2. Isi Cell A2 dengan nama "Ahmad"
3. Isi Cell B2 dengan tanggal lahir "01/02/2000"
4. Isi Cell C2 dengan tanggal hari ini secara manual
"04/04/2000" atau dengan "=TODAY()" untuk mendapatkan
tanggal hari ini secara otomatis sesuai setting komputer. bisa juga dengan
fungsi NOW seperti contoh sebelumnya.
5. Isi Cell D2 dengan rumus excel :
Rumus Excel
=DATEDIF(B2;C2;"Y")
6. Isi Cell E2 dengan rumus excel :
Rumus Excel
=DATEDIF(B2;C2;"YM")
7. Isi Cell F2 dengan rumus excel :
Rumus Excel
=DATEDIF(B2;C2;"MD")
8. Untuk Cell G2 merupakan gabuangan dari ketiga rumus
tersebut dengan tambahan operator teks. Isinya
Rumus Excel
=DATEDIF(B2;C2;"Y")&"Tahun"&DATEDIF(B2;C2;"YM")&"Bulan"&DATEDIF(B2;C2;"MD")&" Hari"
9. Selain dengan Operator Teks "&" anda juga
bisa menggabungkan fungsi-fungsi dalam rumus excel dengan fungsi Concatenate.
Masukkan rumus berikut:
Rumus Excel
=CONCATENATE(DATEDIF(B2;C2;"Y");"Tahun";DATEDIF(B2;C2;"YM");"Bulan";DATEDIF(B2;C2;"MD");" Hari")
10. Untuk baris yang lain menyesuaikan. Anda bisa memasukkan
secara manual atau dengan autofill excel seperti yang sudah saya jelaskan
sebelumnya.
Sebagai catatan tambahan bahwa
komputer saya memakai setting bahasa indonesia sehingga memakai tanda pemisah
argument fungsi/rumus excel titik dua(;). Jika komputer anda memakai setting
bahasa Inggris maka pemisah argumentnya memakai koma(,) tanda pemisah argument.
Selain untuk menghitung umur atau
usia, fungsi DATEDIF jga bisa digunakan untuk menghitung masa kerja pegawai.
© Kelas Excel |
